6.5 Ada.Exceptions 패키지

Ada.Exceptions 패키지는 예외 관련 정보를 다루기 위한 타입과 서브프로그램을 제공합니다.

6.5.1 타입 (Types)

Ada.Exceptions 패키지에는 예외를 다루기 위한 타입과 관련 상수가 정의되어 있습니다.

Exception_Id 타입은 각각의 예외를 고유하게 식별하는 타입입니다. NULL_ID 상수는 Exception_Id 타입의 상수로, 어떠한 예외도 나타내지 않습니다. 이 값은 Exception_Id 타입의 기본 초기값으로 사용됩니다.

Exception_Occurrence 타입은 발생한 예외의 특정 인스턴스에 대한 정보를 나타내는 limited private 타입입니다. 예외 처리기에서 when e : others처럼 선언된 상수 e가 이 타입에 해당합니다. NULL_OCCURRENCE 상수는 Exception_Occurrence 타입의 상수로, 어떠한 예외 발생도 나타내지 않습니다. 이 값은 Exception_Occurrence 타입의 기본 초기값으로 사용됩니다.

Exception_Occurrence_Access 타입은 Exception_Occurrence 객체를 가리키는 접근(access) 타입이며 save_occurrence 함수와 함께 사용되어, 예외 발생 정보를 힙(heap)에 저장하거나 다른 태스크로 전달하는 등의 동적 처리를 가능하게 합니다.

6.5.2 예외 정보 조회 (information retrieval)

다음의 함수들은 발생한 예외(Exception_Occurrence)나 예외의 종류(Exception_Id)에 대한 정보를 반환하는 역할을 합니다.

exception_identity (x : Exception_Occurrence) return Exception_Id;

-- 이 함수는 주어진 예외 발생 인스턴스에 대한 예외의 고유 식별자(`Exception_Id`)를 반환합니다.

exception_name (id : Exception_Id) return String;

-- 이 함수는 예외의 고유 식별자인 `Exception_Id`를 매개변수로 받아, 해당 예외의 이름(예: `CONSTRAINT_ERROR`)을 반환합니다. `'identity` 속성으로 얻은 ID 값을 사용할 때 유용합니다.

exception_name (x : Exception_Occurrence) return String;

-- 이 함수는 실제로 발생한 예외의 인스턴스인 `Exception_Occurrence`를 매개변수로 받아, 해당 예외의 이름을 반환합니다. (내부적으로 `exception_name (exception_identity (x))`를 호출하는 것과 동일합니다.) 예외 처리기에서 `when e : others =>`와 같이 예외 발생 정보를 받았을 때 사용합니다.

exception_message (x : Exception_Occurrence) return String;

-- 예외 발생 시 연관된 메시지를 반환합니다. `raise with "메시지";`와 같이 발생한 예외의 경우 해당 메시지를 반환합니다.

exception_information (x : Exception_Occurrence) return String;

-- 구현에 따라 정의된, 디버깅에 유용한 상세 정보를 문자열로 반환합니다.

wide_exception_name (id : Exception_Id) return Wide_String;

-- `Exception_Name`과 유사하지만, 예외의 전체 확장 이름을 `Wide_String` 타입으로 반환합니다.

wide_exception_name (x : Exception_Occurrence) return Wide_String;

-- 주어진 예외 발생(x)에 대한 예외 이름을 `Wide_String` 타입으로 반환합니다.

wide_wide_exception_name (id : Exception_Id) return Wide_Wide_String;

-- 예외의 전체 확장 이름을 `Wide_Wide_String` 타입으로 반환합니다.

wide_wide_exception_name (x : Exception_Occurrence) return Wide_Wide_String;

-- 주어진 예외 발생(x)에 대한 예외 이름을 `Wide_Wide_String` 타입으로 반환합니다.

-- 예외 정보 조회 예시

with Ada.Text_IO, Ada.Exceptions;

procedure information_example is

  use Ada.Exceptions;

  My_Error : exception;

begin

  -- 예외와 함께 메시지 발생

  raise My_Error with "데이터 처리 중 오류 발생";

exception

  when e : others =>

    Ada.Text_IO.put_line ("예외가 포착되었습니다.");

    Ada.Text_IO.put_line ("예외 이름: " & exception_name (e));

    Ada.Text_IO.put_line ("예외 메시지: " & exception_message (e));

    Ada.Text_IO.put_line ("구현 정의 정보: " & exception_information (e));

end information_example;

6.5.3 예외 발생 및 전파 (Raising and Propagation)

다음의 프로시저들은 예외를 능동적으로 발생시켜 프로그램의 정상적인 실행 흐름을 중단시키는 역할을 합니다.

raise_exception (e       : in Exception_Id;

                 message : in String := "");

-- `Exception_Id`로 식별되는 예외를 주어진 메시지와 함께 발생시키는 프로시저입니다.

reraise_occurrence (x : in Exception_Occurrence);

-- 주어진 `Exception_Occurrence`를 다시 발생시킵니다. 이는 예외 처리기 내에서만 사용 가능한 `raise;` 문과 달리, 예외 처리기 외부에서도 원래의 예외 발생 정보를 그대로 전파할 수 있게 합니다.

-- 예외 발생 및 전파 예시:

-- 하위 루틴에서 발생한 예외를 상위 루틴으로 전달하고 메시지를 출력

with Ada.Text_IO, Ada.Exceptions;

procedure propagation_example is

  use Ada.Exceptions;

  procedure inner_routine is

    My_Custom_Error : exception;

  begin

    -- `raise_exception`을 사용하여 사용자 정의 예외와 메시지를 함께 발생시킴

    raise_exception (My_Custom_Error'identity, "입력값이 유효하지 않습니다.");

  exception

    when e : others =>

      Ada.Text_IO.put_line ("내부(하위) 루틴에서 예외 포착: " &

                            exception_name (e));

      -- 포착된 예외를 다시 발생시켜 외부(상위) 루틴으로 전달

      reraise_occurrence (e);

  end inner_routine;

begin

  begin

    inner_routine;

  exception

    when e : others =>

      Ada.Text_IO.put_line ("외부(상위) 루틴에서 예외 재포착: " &

                            exception_name (e));

      Ada.Text_IO.put_line ("메시지: " & exception_message (e));

  end;

end propagation_example;

6.5.4 예외 발생 정보 관리 (Occurrence Management)

다음의 서브프로그램들은 Exception_Occurrence 객체 자체를 복사, 저장, 또는 스트림을 통해 전송하는 등 관리하는 역할을 합니다.

save_occurrence (target : out Exception_Occurrence;

                 source : in  Exception_Occurrence);

-- `source` 예외 발생 인스턴스를 `target` 으로 복사합니다.

save_occurrence (source : Exception_Occurrence)

return Exception_Occurrence_Access;

-- 새로운 `Exception_Occurrence` 객체를 동적으로 할당하고 `source`의 내용을 복사한 후, 해당 객체를 가리키는 `Exception_Occurrence_Access` 타입의 값을 반환합니다.

write_exception_occurrence (

  stream : not null access Ada.Streams.Root_Stream_Type'class;

  item   : in Exception_Occurrence);

-- 예외 발생 인스턴스에 대한 표현을 스트림에 기록합니다.

read_exception_occurrence (

  stream : not null access Ada.Streams.Root_Stream_Type'class;

  item   : out Exception_Occurrence);

-- 스트림으로부터 예외 발생 인스턴스를 재구성합니다. 이는 다른 파티션(partition)에 기록된 예외도 포함합니다.

-- `save_occurrence`를 활용한 예외 정보 관리 예시

with Ada.Text_IO, Ada.Exceptions, Ada.Integer_Text_IO;

with Ada.IO_Exceptions;

procedure save_example is

  use Ada.Exceptions;

  function get_input return Integer is

    value : Integer;

  begin

    Ada.Text_IO.put ("숫자를 입력하세요 (0 입력 시 예외 발생): ");

    Ada.Integer_Text_IO.get (value);

    return value;

  end get_input;

  -- 예외 정보를 저장할 변수

  err_occ : Exception_Occurrence;

begin

  begin

    declare

      v : constant Integer := get_input;

    begin

      -- 입력값으로 나눗셈 수행 (0 입력 시 예외 발생)

      Ada.Text_IO.put_line ("결과: " & Integer'image (10 / v));

    exception

      -- 내부 블록에서 발생한 모든 예외 처리

      when e : others =>

        Ada.Text_IO.put_line ("예외가 발생했습니다 (내부 블록).");

        save_occurrence (err_occ, e);

    end;

  exception

    -- 입력 스트림 종료 예외 처리

    when e : Ada.IO_Exceptions.End_Error =>

      Ada.Text_IO.put_line ("오류: 입력 스트림이 종료되었습니다.");

      -- 예외 정보를 저장하여 일관된 처리 유지

      save_occurrence (err_occ, e);

    -- 외부 블록에서 발생한 기타 예외 처리

    when e : others =>

      Ada.Text_IO.put_line ("예외가 발생했습니다 (외부 블록).");

      save_occurrence (err_occ, e);

  end;

  Ada.Text_IO.put_line ("저장된 예외 정보:");

  if exception_identity (err_occ) /= NULL_ID then

    Ada.Text_IO.put_line ("예외 이름: " & exception_name (err_occ));

    Ada.Text_IO.put_line ("예외 메시지: " & exception_message (err_occ));

  else

    Ada.Text_IO.put_line ("저장된 예외가 없습니다.");

  end if;

end save_example;

6.5.5 'identity 속성

'identity 속성은 예외의 이름으로부터 시스템이 내부적으로 사용하는 고유 식별값(Exception_Id 타입의 값)을 얻어오는 데 사용됩니다. 이 속성은 프로그래머가 직접 선언한 예외와 Constraint_Error처럼 언어에 미리 정의된 예외 모두에 사용할 수 있습니다.

예를 들어, Ada.Exceptions.raise_exception 프로시저를 통해 특정 예외를 발생시키려면 해당 예외의 Exception_Id 값이 필요합니다. 이때 어떤 예외를 발생시킬지 이름을 알고 있다면 'identity 속성을 사용하고, 예외 처리기 안에서 어떤 예외가 발생했는지 모르는 상황이라면 exception_identity 함수를 사용하여 Exception_Id 값을 얻을 수 있습니다.

예시:

with Ada.Text_IO, Ada.Exceptions;

procedure id_attribute_example is

  use Ada.Exceptions;

  -- 사용자 정의 예외 선언

  Overflow  : exception;

  Underflow : exception;

begin

  -- 'identity 속성을 사용하여 예외 발생시키기

  Ada.Exceptions.raise_exception (Overflow'identity,

                                  "Overflow detected manually.");

exception

  when e : others =>

    Ada.Text_IO.put_line ("An exception was caught.");

    -- exception_identity 함수를 사용하여 발생한 예외의 ID를 얻음

    declare

      the_id : constant Ada.Exceptions.Exception_Id :=

        Ada.Exceptions.exception_identity (e);

    begin

      Ada.Text_IO.put_line ("Message: " & Ada.Exceptions.exception_message (e));

      -- 얻어낸 ID를 사용하여 어떤 예외인지 확인

      if the_id = Overflow'identity then

        Ada.Text_IO.put_line ("The exception was Overflow.");

      elsif the_id = Underflow'identity then

        Ada.Text_IO.put_line ("The exception was Underflow.");

      else

        Ada.Text_IO.put_line ("It was some other exception.");

      end if;

    end;

end id_attribute_example;

https://nimfsoft.art/ko/books/ada-programming/#65-adaexceptions-%ED%8C%A8%ED%82%A4%EC%A7%80

님프소프트 - Ada 프로그래밍 (초안)

님프소프트 - Ada 프로그래밍 (초안)

nimfsoft.art

오늘은 여기까지입니다. 6.6절부터 작성해야되요. ㅠㅠ